Πρόγραμμα μαζικής μετατροπής greeklish

[kesogdem]

Καλή χρονιά σέ ολους.

Ψάχνω πρόγραμμα μαζικής μετατροπής τίτλων τραγουδιών από greeklish σέ ελληνικά καί αντίστροφα.
Ευχαριστώ.

[hemlock]

Χμμμ δε νομιζω να υπαρχει τετοιο προγραμματακι...

[harris]

Yπάρχουν διάφορα προγραμματάκια που κάνουν μαζική αλλαγή ονομάτων αρχείων (όχι μόνο mp3 αλλά γενικώς)... Ψάξε στο google για batch rename

Αλλά όχι αυτόματη μετατροπή greeklish που ζητάς...

[bill2003]

Όντως πολύ custom πρόγραμμα αυτό που ζητάς, είτε πρόκειται για αλλαγή του filename είτε των ID3 tags (ακόμη πιο δύσκολο ).

Ή φτιάχνεις κάτι δικό σου από το μηδέν ή τα κάνεις όλα με το χέρι

[deniSun]

Για αλλαγή ονομάτων αρχείου ίσως να βρεις αλλά για ID3 tags δεν νομίζω.

[gcapnias]

Νομίζω ότι το παρακάτω είναι αυτό που ζητάς... Το είχα φτιάξει πριν από χρόνια για αυτό το σκοπό. Βάλε τον κώδικα μέσα σε ένα αρχείο κειμένου με όνομα convert.vbs και τοποθέτησέ το μέσα στο κατάλογο με τα τραγούδια που θέλεις να αλλάξεις τους τίτλους και τρέξτο...

Η συνέχεια επί του σκληρού σου...

 
' Script για αλλαγή ονομάτων αρχείων
' © 2003 George J. Capnias
Option Explicit
Dim sGreekish, sHellenic
Dim caseCode
 sGreekish="ABGDEZH8IKLMN3OPRSTYFXCWabgdezh8iklmn3oprstyfxcwaehioywAEHIOYW"
 sHellenic="ΑΒΓΔΕΖΗΘΙΚΛΜΝΞΟΠΡΣΤΥΦΧΨΩαβγδεζηθικλμνξοπρστυφχψωάέήίόύώΆΈΉΊΌΎΏ"
 'Select function to do
 ' case 0: To Nice
 ' case 1: To Lower
 ' case 2: To Upper
 ' case 3: From Greekish To Greek
 ' case 4: From Greek To Greekish
 caseCode=inputBox("0: Σε κεφαλαια-πεζά τίτλου" & vbCrLf & "1: Σε πεζά" & vbCrLf & "2: Σε κεφαλαία" & vbCrLf & "3: Από Λατινικά σε Ελληνικά" & vbCrLf & "4: Από Ελληνικά σε Λατινικά", "Κάντε μια επιλογή", 0)
Call filesConvertCase(".")
msgbox "Η μετατροπή των ονομάτων των αρχείων, ολοκληρώθηκε!", 64, "Μετρατοπή Ονομάτων"
Function filesConvertCase(szFolder)
Dim oFileSystemObject
Dim oFolder
Dim oFoldersCollection
Dim oFilesCollection
Dim oFile
Dim szPath
Dim szFileName
Dim szExtension
 Set oFileSystemObject = CreateObject("Scripting.FileSystemObject")
 Set oFolder = oFileSystemObject.GetFolder(szFolder)
 Set oFilesCollection = oFolder.Files
 For Each oFile In oFilesCollection
  szPath=""
  szFileName=oFile.Path
  szExtension=""
 
  if (InStrRev(szFileName, "\")>0) then
   szPath=Left(szFileName, InStrRev(szFileName, "\"))
   szFileName=Mid(szFileName, InStrRev(szFileName, "\")+1)
  end if
  if (InStrRev(szFileName, ".")>0) then
   szExtension=LCase(Mid(szFileName, InStrRev(szFileName, ".")))
   szFileName=Left(szFileName, InStrRev(szFileName, ".")-1)
  End if
  'Select job to do  
  szFileName=convertCase(caseCode, szFileName)
 
  szPath=szPath & szFileName & szExtension
  on error resume next
  oFile.Move (szPath)
  on error goto 0
 Next
 Set oFilesCollection=Nothing
 Set oFile=Nothing
 
 Set oFoldersCollection = oFolder.SubFolders
 For Each oFolder In oFoldersCollection
  szPath=LCase(oFolder.Path)
  szFileName=Mid(szPath, InStrRev(szPath, "\")+1)
  szPath=Left(szPath, InStrRev(szPath, "\"))
  'Select job to do
  szFileName=convertCase(caseCode, szFileName)
  szPath=szPath & szFileName
  on error resume next
  call oFolder.Move(szPath)
  on error goto 0
  call filesConvertCase(szPath)
 Next
 Set oFoldersCollection=Nothing
 Set oFolder=Nothing
End Function
Function convertCase(caseCode, szFileName)
 szFileName=fixGeneral(szFileName)
 select case caseCode
  case 0
   convertCase=convert2NiceCase(szFileName)
  case 1
   convertCase=convert2LowerCase(szFileName)
  case 2
   convertCase=convert2UpperCase(szFileName)
  case 3
   convertCase=convert4Greekish(szFileName)
  case 4
   convertCase=convert4Greek(szFileName)
  case else
   MsgBox "Not a valid conversion!"
   convertCase=szFileName
 end select
 
End Function
Function convert2NiceCase(szFileName)
Dim sSubfixesnotes
Dim iCounter
Dim lngPosition
 sSubfixesnotes=" -_=+()"
 
 szFileName=LCase(szFileName) 
 for iCounter=1 to Len(sSubfixesnotes)
  lngPosition=1
  Do While (InStr(lngPosition+1, szFileName, Mid(sSubfixesnotes, iCounter, 1))>0)
   lngPosition=InStr(lngPosition+1, szFileName, Mid(sSubfixesnotes, iCounter, 1))
   szFileName=Left(szFileName, lngPosition) & UCase(Mid(szFileName, lngPosition+1, 1)) & Mid(szFileName, lngPosition+2)
  Loop
 Next
 szFileName=UCase(Left(szFileName,1)) & Mid(szFileName,2) 
 szFileName=fixSubfixes(szFileName)
 
 convert2NiceCase=szFileName
End Function
Function convert2LowerCase(szFileName)
 szFileName=LCase(szFileName)
 szFileName=fixSubfixes(szFileName)
 convert2LowerCase=szFileName
End Function
Function convert2UpperCase(szFileName)
 szFileName=UCase(szFileName)
 convert2UpperCase=szFileName
End Function
Function convert4Greekish(szFileName)
Dim iCounter
Dim sChar
Dim lngPosition
Dim sPrefix
Dim sSubfix
 For iCounter=1 to Len(szFileName)
  sChar=Mid(szFileName, iCounter, 1)
  lngPosition=InStr(sGreekish, sChar)
  if lngPosition>0 then
   if iCounter>1 then
    sPrefix=Left(szFileName, iCounter-1)
   else
    sPrefix=""
   end if
   if iCounter<Len(szFileName) then
    sSubfix=Mid(szFileName, iCounter+1)
   else
    sSubfix=""
   end if
   'msgbox(sPrefix & Mid(sHellenic, lngPosition, 1) & sSubfix)
   szFileName= sPrefix & Mid(sHellenic, lngPosition, 1) & sSubfix
  end if
 Next
 convert4Greekish=szFileName
End Function
Function convert4Greek(szFileName)
Dim iCounter
Dim sChar
Dim lngPosition
Dim sPrefix
Dim sSubfix
 For iCounter=1 to Len(szFileName)
  sChar=Mid(szFileName, iCounter, 1)
  lngPosition=InStr(sHellenic, sChar)
  if lngPosition>0 then
   if iCounter>1 then
    sPrefix=Left(szFileName, iCounter-1)
   else
    sPrefix=""
   end if
   if iCounter<Len(szFileName) then
    sSubfix=Mid(szFileName, iCounter+1)
   else
    sSubfix=""
   end if
   'msgbox(sPrefix & Mid(sGreekish, lngPosition, 1) & sSubfix)
   szFileName= sPrefix & Mid(sGreekish, lngPosition, 1) & sSubfix
  end if
 Next
 convert4Greek=szFileName
End Function
 
Function fixSubfixes(szFileName)
Dim sSubfixesnotes
Dim sSubfixesChecks
Dim sSubfixesReplaces
Dim iCounter
Dim iCounterChecks
Dim lngPosition
 sSubfixesnotes=" -_=+()"
 sSubfixesChecks="σ"
 sSubfixesReplaces="ς"
 
 for iCounter=1 to Len(sSubfixesnotes)
  lngPosition=1
  Do While (InStr(lngPosition+1, szFileName, Mid(sSubfixesnotes, iCounter, 1))>0)
   lngPosition=InStr(lngPosition+1, szFileName, Mid(sSubfixesnotes, iCounter, 1))
   For iCounterChecks=1 to Len(sSubfixesChecks)
    If Mid(szFileName, lngPosition-1, 1)=Mid(sSubfixesChecks, iCounterChecks, 1) Then
     szFileName=Left(szFileName, lngPosition-2) & Mid(sSubfixesReplaces, iCounterChecks, 1) & Mid(szFileName, lngPosition)
    End If
   Next
  Loop
  For iCounterChecks=1 to Len(sSubfixesChecks)
   if Right(szFileName, 1)=Mid(sSubfixesChecks, iCounterChecks, 1) then
    szFileName=Left(szFileName, Len(szFileName)-1) & Mid(sSubfixesReplaces, iCounterChecks, 1)
   end if
  Next
 Next
 fixSubfixes=szFileName
End Function
Function fixGeneral(szFileName)
 szFileName=Trim(szFileName)
 do while InStr(szFileName, "  ")>0
  szFileName=Replace(szFileName, "  ", " ")
 loop
 
 fixGeneral=szFileName
End Function

George J.

[harris]

Μετονόμασε μέχρι και το όνομά τους από convert.vbs σε ψονvερτ.vbs

Στα εύκολα τα πάει καλά αλλά στα δύσκολα δεν τα βγάζει πέρα γιατί δεν αναγνωρίζει δίφθογγους στα greeklish (για παράδειγμα το "tha" δεν το κάνει "θα", αλλά "τηα")...

Το "8a" όμως το έκανε "θα"

[yiannisbot]

Γεια χαρα! Διάβασα χτες μία σχετική απάντηση του μέλους gcapnias ο οποίος έφτιαξε ένα προγραμματάκι για να μετατρέπει τους τίτλους των τραγουδιών απο greek σε greeklish ή κ το αντίστροφο.. Η ιστοσελίδα είναι αυτή http://www.adslgr.com/forum/showthread.php?t=69065
κ η απάντηση είναι στο τέλος της ιστοσελίδας
Αυτό που θα ρωτήσω αν το ξέρει κάποιος,το ρώτησα κ στον ίδιο αλλά ίσως να μην είναι ενεργό μέλος πια, δεν ξέρω..οπότε θα ήθελα να μάθω αν ξέρει κάποιος πως να λειτουργήσω αυτό το πρόγραμμα. Εκανα copy όλο το παραθυράκι που λέει code κ το έκανα paste σε ένα εγγραφο word. Απο κει κ πέρα όμως δεν ξέρω πως να συνεχίσω.. Αν μπορεί κάποιος να με βοηθήσει θα ήμουν ευγνώμων.
Ευχαριστώ
Γιάννης

[ZackNV]

Όπως το κόβω, το προγραμματάκι αυτό είναι γραμμένο σε Visual Basic. Συνεπώς, για να το τρέξεις αντέγραψε τον κώδικα σε κάποιο txt αρχείο στο οποίο θα βάλεις επέκταση .vbs και θα το τρέξεις με την VB. Ελπίζω να βοήθησα κάπως.

[vasilis21]

Μηπως μπορει καποιος ο οποίος γνωριζει Visual Basic να μας πει πως μπορουμε να αλλαξουμε λιγο τον παραπανω κωδικα ωστε να βγαζει τους διφθογγους π.χ ps->ψ th->θ κ.τ.λ.?

[yiannisbot]

zack nv σ ευχαριστώ για την απαντηση
δυστυχώς δε γνωρίζω τίποτα απο VISUAL BASIC
αν δεν είναι δύσκολο μπορείς να μου πεις λίγα λόγια για το τι πρέπει να κάνω για να τρέξει το πρόγραμμα?

το περιεχόμενο του code το έχω ήδη αποθηκεύσει σε word με επέκταση vbs

σ ευχαριτσώ και πάλι

[ZackNV]

Δυστυχώς δεν είμαι ειδικός γι' αυτή τη γλώσσα προγραμματισμού. Έχοντας όμως δουλέψει αρκετά σε παρεμφερή γλώσσα (quick basic 4.5) μπορώ και αναγνωρίζω κάποιες εντολές. Ελπίζω κάποιος άλλος να μπορείς να σου δώσει συμβουλές πάνω στον κώδικα.

[my8os]

Δοκιμάστε το ant renamer, ένα δωρεάν πρόγραμμα εδώ με τον κώδικα διαθέσιμο, http://www.antp.be/software/renamer

Έχω ακούσει καλά λόγια γι' αυτό.

[gatoz]

Yπάρχουν διάφορα προγραμματάκια που κάνουν μαζική αλλαγή ονομάτων αρχείων (όχι μόνο mp3 αλλά γενικώς)... Ψάξε στο google για batch rename

Αλλά όχι αυτόματη μετατροπή greeklish που ζητάς...

Το δικό μου, μετατρέπει σε greeklish ολα τα επιλεγμένα αρχεία ή δημιουργεί αντίγραφα...
Διαβάζει τον κατάλογο και τους υποκαταλόγους, ψάψνει για mp3 και κάνει batch μετονομασία των mp3 σε αγγλικά
http://rapidshare.com/files/133816641/mp3renamer.rar
και η νέα έκδοση με επιπλέον tags convert, Gr to Eng, Work with Copies, Change mp3 file order!!!
Εχει οδηγίες μέσα
http://rapidshare.com/files/133901053/mp3renamer.rar

[kozi1989]

Το δικό μου, μετατρέπει σε greeklish ολα τα επιλεγμένα αρχεία ή δημιουργεί αντίγραφα...
Διαβάζει τον κατάλογο και τους υποκαταλόγους, ψάψνει για mp3 και κάνει batch μετονομασία των mp3 σε αγγλικά
http://rapidshare.com/files/133816641/mp3renamer.rar
και η νέα έκδοση με επιπλέον tags convert, Gr to Eng, Work with Copies, Change mp3 file order!!!
Εχει οδηγίες μέσα
http://rapidshare.com/files/133901053/mp3renamer.rar

Μπράβο!!!Τέλειο εκτός του ότι πρέπει να υπάρξουν βελτιώσεις στην μετατροπή από greeklish σε ελληνικά.
Να προτείνω κάτι?
Μπορείς να περάσεις λεξιλόγιο ώστε να κάνει μετατροπή λέξεων αντί για γράμματα?Δηλαδή να δουλέψουμε αρκετά άτομα το project και να κάνουμε μιά βάση με λέξεις greeklish και συνδυασμούς.
Κατα τα άλλα η μαζική μετονομασία είναι καταπληκτική!!Επέκτεινε την αν μπορείς και σε directories-φακέλους να αλλάζει.

Και με τα tags κάποια δεν τα μετατρέπει.