[ROS7] Dual Wan Recursive Routes

[seatakias]

Στο routing βαλε στους 2 πρωτους κανονες target-scope=12

Φίλε σε ευχαριστώ για την απάντηση σου.
Άλλαξα το target-scope σε 12 και μου έπαιξε κατευθείαν. Στο speetdest μου έβγαζε την ταχύτητα και απο τις δύο wan.

Όταν έκλεισα την WAN 1 (εκλεισα το Modem) το failover δεν έπαιξε. Επίσης δεν μου φώρτονε καμία σελίδα.
Όταν ξανα ενεργοποίησα την WAN1 , επανήλθε το ίντερνετ και σε speed test παίρνει μόνο την ταχύτητα της WAN1.
Εχω κάνει επανεκκινήσεις αλλά δεν λέει να διορθωθεί.


Τι μπορεί να είναι λάθος?

[macro]

Επειδη δεν εχεις failover για αυτο. Για να εχεις πρεπει να κανεις ping σε externals hosts κατι το οποιο εσυ δε κανεις. Διαβασε το τοπικ απο την αρχη και θα βρεις την ακρη, αλλιως ξαναελα.

[seatakias]

Επειδη δεν εχεις failover για αυτο. Για να εχεις πρεπει να κανεις ping σε externals hosts κατι το οποιο εσυ δε κανεις. Διαβασε το τοπικ απο την αρχη και θα βρεις την ακρη, αλλιως ξαναελα.

Σαν external ip τι μπορώ βάλω? Νόμιζα ότι αρκούν οι Ip της google.
Ευχαριστώ για την βοήθεια.

[macro]

Λαθος μου, τωρα ειδα οτι εχεις external hosts, κανονικα θα επρεπε να σου δουλευει. Δλδ ποση ωρα περιμενεις και δε στο γυριζει. Θελει μερικα δευτερολεπτα.

[seatakias]

Λαθος μου, τωρα ειδα οτι εχεις external hosts, κανονικα θα επρεπε να σου δουλευει. Δλδ ποση ωρα περιμενεις και δε στο γυριζει. Θελει μερικα δευτερολεπτα.

Και δεκα λεπτα να το αφήσω δεν κάνει failover!!Επίσης και το modem να βγάλω απο την πρίζα πάλι δεν γυρίζει.
Γυρίζει στην wan2 μόνο όταν κάνω disable τον κανόνα χειροκίνητα όπως δείχνω στην φωτογραφία.

[macro]

Κανε αλλη μια δοκιμη. Αλλαξε το target scope σε 12 και στους to_wan1, to_wan2 κανονες

[seatakias]

Κανε αλλη μια δοκιμη. Αλλαξε το target scope σε 12 και στους to_wan1, to_wan2 κανονες

Έβαλα και στους κανόνες που μου είπες target scope 12. Χωρίς αποτέλεσμα!!

Δοκίμασα τους παρακατω κανόνες με netwatch και το failover παίζει κανονικά, αλλα δεν μου προσθέτει τις ταχύτητες των WAN.

/ip route
add dst-address="0.0.0.0/0" target-scope="10" distance="1" gateway="192.168.2.1" comment="ISP-1" check-gateway="ping" scope="30"
add dst-address="0.0.0.0/0" target-scope="10" distance="2" gateway="192168.4.1" comment="ISP-2" check-gateway="ping" scope="30"
add dst-address="8.8.8.8" target-scope="10" distance="1" gateway="192.168.2.1" comment="ISP-1-Check" scope="30"
add dst-address="8.8.4.4" target-scope="10" distance="1" gateway="192168.4.1" comment="ISP-2-Check" scope="30"
/tool netwatch
add host="8.8.8.8" interval="5s" down-script="/ip route disable [find comment=\"ISP-1\"]" up-script="/ip route enable [find comment=\"ISP-1\"]" comment="ISP-1"
add host="8.8.4.4" interval="5s" down-script="/ip route disable [find comment=\"ISP-2\"]" up-script="/ip route enable [find comment=\"ISP-2\"]" comment="ISP-2"

Μπορώ να αφήσω το netwatch και με κάποιο τρόπο να προσθέσω το κανόνα για να προσθέτω τις δύο WAN?

Mήπως έχω λάθος στο mangle και για αυτό δεν μου παίζει

    chain=prerouting action=accept dst-address=192.168.1.0/24 in-interface=LAN log=no log-prefix="" 

    chain=prerouting action=accept dst-address=192.168.2.0/24 in-interface=LAN 

    chain=prerouting action=accept dst-address=192.168.4.0/24 in-interface=LAN log=no log-prefix="" 

    chain=prerouting action=accept dst-address=10.227.10.0/24 in-interface=LAN log=no log-prefix="" 

    chain=prerouting action=accept dst-address=192.168.3.0/24 in-interface=LAN log=no log-prefix="" 

    chain=prerouting action=mark-connection new-connection-mark=WAN1_conn connection-mark=no-mark in-interface=ether1 

    chain=prerouting action=mark-connection new-connection-mark=WAN2_conn connection-mark=no-mark in-interface=ether2 log=no log-prefix="" 

    chain=prerouting action=mark-connection new-connection-mark=WAN1_conn dst-address-type=!local connection-mark=no-mark in-interface=LAN per-connection-classifier=both-addresses:2/0 

    chain=prerouting action=mark-connection new-connection-mark=WAN2_conn dst-address-type=!local connection-mark=no-mark in-interface=LAN per-connection-classifier=both-addresses:2/1 

    chain=prerouting action=mark-routing new-routing-mark=to_WAN1 connection-mark=WAN1_conn in-interface=LAN 

    chain=prerouting action=mark-routing new-routing-mark=to_WAN2 connection-mark=WAN2_conn in-interface=LAN 

    chain=output action=mark-routing new-routing-mark=to_WAN1 connection-mark=WAN1_conn 

    chain=output action=mark-routing new-routing-mark=to_WAN2 connection-mark=WAN2_conn

[macro]

Πως τσεκαρεις οτι δε γινεται bonding των γραμμων? Στο ookla speedtest δοκιμασες με τσεκαρισμενο το multi στα connections? Ειναι ακριβως απο κατω απο εκει που διαλεγεις server για να κανεις τεστ.

[seatakias]

Τελικά σήμερα που είχα χρόνο. Εκανα επαναφορά του router και το ρυθμισα απο την αρχή.
Με τις παρακάτω ρυθμίσεις μου έπαιξε κανονικά. Ευχαριστώ για την βοήθεια.

/ip firewall mangle
add action=mark-connection chain=input in-interface="ether1" new-connection-mark="cm-ether1" passthrough=yes 
add action=mark-connection chain=input in-interface="ether2 " new-connection-mark="cm-ether2 " passthrough=yes
add action=mark-routing chain=output connection-mark="cm-ether1" new-routing-mark="to-ether1" passthrough=yes 
add action=mark-routing chain=output connection-mark="cm-ether2 " new-routing-mark="to-ether2 " passthrough=yes 
add action=mark-connection chain=prerouting dst-address-list=!LOCAL-IP dst-address-type=!local new-connection-mark="cm-ether1" passthrough=yes per-connection-classifier=both-addresses-and-ports:2/0 src-address-list=LOCAL-IP
add action=mark-connection chain=prerouting dst-address-list=!LOCAL-IP dst-address-type=!local new-connection-mark="cm-ether2 " passthrough=yes per-connection-classifier=both-addresses-and-ports:2/1 src-address-list=LOCAL-IP
add action=mark-routing chain=prerouting connection-mark="cm-ether1" dst-address-list=!LOCAL-IP new-routing-mark="to-ether1" passthrough=yes src-address-list=LOCAL-IP
add action=mark-routing chain=prerouting connection-mark="cm-ether2 " dst-address-list=!LOCAL-IP new-routing-mark="to-ether2 " passthrough=yes src-address-list=LOCAL-IP

/ip route
add distance=251 gateway=192.168.2.1
add distance=252 gateway=192.168.4.1
add gateway=192.168.2.1 routing-table=to-ether1
add gateway=192.168.4.1 routing-table=to-ether2
add dst-address=4.2.2.1/32 gateway=192.168.2.1 scope=11
add dst-address=4.2.2.2/32 gateway=192.168.4.1 scope=11
add check-gateway=ping distance=10 gateway=4.2.2.1 targetscope=11
add check-gateway=ping distance=20 gateway=4.2.2.2 targetscope=11

[BillyVan]

Το τσεκαρα πριν λιγο σε σχεση με ενα δικο μου και δειχνει να μην παιζει.

Αν εχεις την καλοσυνη κανε ενα κοπο και ξανατσεκαρε το.

Ανεβασε ολο το expοrt (αφαιρεσε τα κριτικαλ)

Ευχαριστω

[macro]

Τι δε σου δουλευε εσενα?

[BillyVan]

Οπως το εβαλε δεν μου κανει bond τις γραμμες.



Απλό failover σε ros7

/routing table add disabled=no fib name=rtab-1
/routing table add disabled=no fib name=rtab-2

/ip route add distance=1 gateway=10.30.30.1
/ip route add distance=2 gateway=10.40.40.1
/ip route add gateway=10.30.30.1 routing-table=rtab-1
/ip route add gateway=10.40.40.1 routing-table=rtab-2

Οπως το λεει αυτος που το εβαλε στο Μικροτικ Φορουμ

Fault tolerance through recursive routes

/routing table add disabled=no fib name=rtab-1
/routing table add disabled=no fib name=rtab-2

/ip firewall mangle add action=mark-connection chain=prerouting connection-mark=no-mark in-interface=ether1 new-connection-mark=con-isp1 passthrough=yes
/ip firewall mangle add action=mark-connection chain=prerouting connection-mark=no-mark in-interface=ether2 new-connection-mark=con-isp2 passthrough=yes
/ip firewall mangle add action=mark-routing chain=prerouting connection-mark=con-isp1 in-interface-list=!WAN new-routing-mark=rtab-1 passthrough=yes
/ip firewall mangle add action=mark-routing chain=prerouting connection-mark=con-isp2 in-interface-list=!WAN new-routing-mark=rtab-2 passthrough=yes
/ip firewall mangle add action=mark-routing chain=output connection-mark=con-isp1 new-routing-mark=rtab-1 passthrough=yes
/ip firewall mangle add action=mark-routing chain=output connection-mark=con-isp2 new-routing-mark=rtab-2 passthrough=yes


/ip route add disabled=no distance=1 dst-address=0.0.0.0/0 gateway=10.30.30.1 pref-src="" routing-table=main scope=30 suppress-hw-offload=no target-scope=10
/ip route add disabled=no distance=2 dst-address=0.0.0.0/0 gateway=10.40.40.1 pref-src="" routing-table=main scope=30 suppress-hw-offload=no target-scope=10
/ip route add gateway=10.30.30.1 routing-table=rtab-1
/ip route add gateway=10.40.40.1 routing-table=rtab-2
/ip route add dst-address=208.67.220.220/32 gateway=10.30.30.1 scope=11
/ip route add dst-address=208.67.222.222/32 gateway=10.40.40.1 scope=11
/ip route add check-gateway=ping disabled=no distance=1 dst-address=0.0.0.0/0 gateway=208.67.220.220 pref-src="" routing-table=main scope=30 suppress-hw-offload=no target-scope=11
/ip route add check-gateway=ping disabled=no distance=2 dst-address=0.0.0.0/0 gateway=208.67.222.222 pref-src="" routing-table=main scope=30 suppress-hw-offload=no target-scope=11

Και τέλος αναλόγως πως θελουμε το balance (μοιρασμα βαρους ή προσθεση)

/routing table add disabled=no fib name=rtab-1
/routing table add disabled=no fib name=rtab-2


/ip firewall mangle add action=mark-connection chain=input in-interface=ether1 new-connection-mark=con-isp1 passthrough=yes
/ip firewall mangle add action=mark-connection chain=input in-interface=ether2 new-connection-mark=con-isp2 passthrough=yes
/ip firewall mangle add action=mark-routing chain=output connection-mark=con-isp1 new-routing-mark=rtab-1 passthrough=yes
/ip firewall mangle add action=mark-routing chain=output connection-mark=con-isp2 new-routing-mark=rtab-2 passthrough=yes

#Αναλόγως τι θέλουμε βάζουμε το 1 ή το 2.
# 1. Με το source μοιραζει το βαρος
/ip firewall mangle add action=mark-connection chain=prerouting dst-address-type=!local in-interface=bridge1 new-connection-mark=con-isp1 passthrough=yes per-connection-classifier=src-address:2/0
/ip firewall mangle add action=mark-connection chain=prerouting dst-address-type=!local in-interface=bridge1 new-connection-mark=con-isp2 passthrough=yes per-connection-classifier=src-address:2/1

# 2. Ετσι τις προσθετει (προσοχη για τραπεζες πρεπει να κανουμε address list με τις ip που πρεπει να βγαινουν μονο απο μια wan)
/ip firewall mangle add action=mark-connection chain=prerouting dst-address-type=!local in-interface=bridge1 new-connection-mark=con-isp1 passthrough=yes per-connection-classifier=both-addresses-and-ports:2/0
/ip firewall mangle add action=mark-connection chain=prerouting dst-address-type=!local in-interface=bridge1 new-connection-mark=con-isp2 passthrough=yes per-connection-classifier=both-addresses-and-ports:2/1


/ip firewall mangle add action=mark-routing chain=prerouting connection-mark=con-isp1 in-interface=bridge1 new-routing-mark=rtab-1 passthrough=yes
/ip firewall mangle add action=mark-routing chain=prerouting connection-mark=con-isp2 in-interface=bridge1 new-routing-mark=rtab-2 passthrough=yes



/ip route add check-gateway=ping disabled=no distance=1 dst-address=0.0.0.0/0 gateway=208.67.220.220 pref-src="" routing-table=main scope=10 suppress-hw-offload=no target-scope=12
/ip route add check-gateway=ping disabled=no distance=1 dst-address=0.0.0.0/0 gateway=208.67.222.222 pref-src="" routing-table=main scope=10 suppress-hw-offload=no target-scope=12
/ip route add disabled=no distance=1 dst-address=208.67.220.220/32 gateway=10.30.30.1 pref-src="" routing-table=main scope=10 suppress-hw-offload=no target-scope=11
/ip route add disabled=no distance=1 dst-address=208.67.222.222/32 gateway=10.40.40.1 pref-src="" routing-table=main scope=10 suppress-hw-offload=no target-scope=11
/ip route add check-gateway=ping disabled=no distance=1 dst-address=0.0.0.0/0 gateway=208.67.220.220 pref-src="" routing-table=rtab-1 scope=30 suppress-hw-offload=no target-scope=12
/ip route add check-gateway=ping disabled=no distance=1 dst-address=0.0.0.0/0 gateway=208.67.222.222 pref-src="" routing-table=rtab-2 scope=30 suppress-hw-offload=no target-scope=12

Διορθωσεις κλπ σιγουρα θα παιρνει αλλα οτι εβαλα το εχω δοκιμασει και παίζει.

[macro]

Εγω θεωρω λαθος το passthrough=yes στο mangles εκτος απο το outpout που μονο εκει χρειαζεται.

[deniSun]

Αναλόγως τις δηλώσεις που έχει από κάτω.

[dalex]

Αναλόγως τις δηλώσεις που έχει από κάτω.

Ε βεβαια! Αμα κατηγοριοποιεις ανα πρωτοκολο/πορτα παρακατω πως θα φτασει εκει αν βγει το passthrough;