Scripts για Mikrotik (όλα μαζεμένα)

[romankonis]

Γιατί χρησιμοποιείτε άλλον DDNS από αυτόν της ΜΤ;

Backup

- - - Updated - - -

https://blog.e-wireless.gr/update-dy...basics-part-6/

Το είδα, thnx

[BillyVan]

Δοκιμασμένα Script που παιζει το noip που έχετε.

1.

##############Script Settings##################

:local NOIPUser "to mail poy exete sto noip"
:local NOIPPass "ton kwdiko sas"
:local WANInter "pppoe-out"
:local NOIPDomain "billyvan.ddns.net"

###############################################

# Get the current IP on the interface
:local currentIP [/ip address get [find interface="$WANInter" disabled=no] address]

# Strip the net mask off the IP address
   :for i from=( [:len $currentIP] - 1) to=0 do={
       :if ( [:pick $currentIP $i] = "/") do={ 
           :set currentIP [:pick $currentIP 0 $i]
       } 
   }

:if ([:resolve $NOIPDomain] != $currentIP) do={
      /tool fetch mode=http user=$NOIPUser password=$NOIPPass url="http://dynupdate.no-ip.com/nic/update\3Fhostname=$NOIPDomain&myip=$currentIP" keep-result=no
      :log info "NO-IP Update: $NOIPDomain - $currentIP"
}

2 για noip κι αυτο

# No-IP automatic Dynamic DNS update

#--------------- Change Values in this section to match your setup ------------------

# No-IP User account info
:local noipuser "to mail poy exete sto noip"
:local noippass "ton kwdiko sas"

# Set the hostname or label of network to be updated.
# Hostnames with spaces are unsupported. Replace the value in the quotations below with your host names.
# To specify multiple hosts, separate them with commas.
:local noiphost "billyvan.noip.com"

# Change to the name of interface that gets the dynamic IP address
:local inetinterface "to interface"

#------------------------------------------------------------------------------------
# No more changes need

:if ([/interface get $inetinterface value-name=running]) do={
# Get the current IP on the interface
  :local currentIP [/ip address get [find interface="$inetinterface" disabled=no] address]

# Strip the net mask off the IP address
  :for i from=( [:len $currentIP] - 1) to=0 do={
     :if ( [:pick $currentIP $i] = "/") do={ 
        :set currentIP [:pick $currentIP 0 $i]
     } 
  }

# The update URL. Note the "\3F" is hex for question mark (?). Required since ? is a special character in commands.
  :local url "http://dynupdate.no-ip.com/nic/update\3Fmyip=$currentIP"
  :local noiphostarray
  :set noiphostarray [:toarray $noiphost]
  
  :foreach host in=$noiphostarray do={
    # Check 1 - resolved IP
    :local resolvedIP [:resolve $host];

    # Check 2 - Saved response from NO-IP
    :local filename ("no-ip_ddns_update-" . $host . ".txt")
    :local savedMatch -1
    :local savedIP "No File";

    if ( [:len [/file find name=$filename]] > 0 ) do={
      :set savedIP [/file get $filename contents]
      :set savedMatch [:find $savedIP $currentIP -1]
    }

    # If either check fails, update IP	
    :if (($currentIP = $resolvedIP) && ($savedMatch >= 0)) do={
      :log info "No-IP: Host $host already on No-IP with IP $resolvedIP"
    } else={
      :log info "No-IP: Sending update for $host - $resolvedIP saved as $savedIP"
      /tool fetch url=($url . "&hostname=$host") user=$noipuser password=$noippass mode=http dst-path=$filename
      :log info "No-IP: Host $host updated on No-IP with IP $currentIP"
    }
  }
} else={
  :log info "No-IP: $inetinterface is not currently running, so therefore will not update."
}

3. Δοκιμασμένο Script για το Dyndns

# Set needed variables
:local username "onoma"
:local password "kwdikos"
:local hostname "billyvan.dyndns.com"

:global dyndnsForce
:global previousIP 

# print some debug info
#:log info ("UpdateDynDNS: username = #$username")
#:log info ("UpdateDynDNS: password = #$password")
#:log info ("UpdateDynDNS: hostname = #$hostname")
:log info ("UpdateDynDNS: previousIP = $previousIP")

# get the current IP address from the internet (in case of double-nat)
/tool fetch mode=http address="checkip.dyndns.org" src-path="/" dst-path="/dyndns.checkip.html"
:delay 1
:local result [/file get dyndns.checkip.html contents]

# parse the current IP result
:local resultLen [:len $result]
:local startLoc [:find $result ": " -1]
:set startLoc ($startLoc + 2)
:local endLoc [:find $result "</body>" -1]
:local currentIP [:pick $result $startLoc $endLoc]
:log info "UpdateDynDNS: currentIP = $currentIP"

# Remove the # on next line to force an update every single time - useful for debugging,
# but you could end up getting blacklisted by DynDNS!

#:set dyndnsForce true

# Determine if dyndns update is needed
# more dyndns updater request details http://www.dyndns.com/developers/specs/syntax.html

:if (($currentIP != $previousIP) || ($dyndnsForce = true)) do={
   :set dyndnsForce false
   :set previousIP $currentIP
   :log info "$currentIP or $previousIP"
   :local result [/tool fetch user=$username password=$password mode=http address="members.dyndns.org" \
      src-path="nic/update?system=dyndns&hostname=$hostname&myip=$currentIP&wildcard=no" \
      dst-path="/dyndns.txt"]
/ ip firewall connection {:foreach r in=[find] do={remove $r}}  
:log info ("CONNECTIONS CLEARED")
   :delay 1
   :local result [/file get dyndns.txt contents]
   :log info ("UpdateDynDNS: Dyndns update needed")
   :log info ("UpdateDynDNS: Dyndns Update Result: ".$result)
   :put ("Dyndns Update Result: ".$result)
} else={
   :log info ("UpdateDynDNS: No dyndns update needed")
}

Στο σκριπτ του Dyndns προς το τελος θα δειτε οτι εχω βαλει να κανει clear τα connections

Με βοήθησε σε συνδέσεις προς voip παρόχους ωστε να καθαρίζουν οι συνδέσεις και να πας απ την αρχη.

[romankonis]

Η καλύτερη λύση που σκέφτηκα να κάνω χωρίς script. Δουλεύει ότι και να γίνει)) Think smart

[RpMz]

Αν σταματήσει να λειτουργεί το cloud dns της MikroTik (όπως έχει γίνει στο παρελθόν), δεν θα λειτουργεί ούτε αυτό.

Είναι μονόδρομος το script.

[macro]

Mια φορα σταματησε το cloud της ΜΤ.......

[BillyVan]

Mια φορα σταματησε το cloud της ΜΤ.......

Τα τελευταια χρονια ειναι σιγουρα 3-4 οι φορες.

Δεν εγινε και κατι να πεσει μια φορα το χρονο.

Οσο αναφορα το cname ειναι γνωστο το δεσιμο που μπορεις να κανεις.

Σκριπτ ομως γραφουμε εδω μεσα για οποιον τα θελει και ειπαμε να τα μαζεψουμε ολα εδω μεσα.

Δε βλεπω ομως να υπαρχει διαθεση.

[macro]

Mια χαρα διαθεση υπαρχει για αυτους που θελουν να μοιραστουν τα scripts και οσοι εχουν.

[deniSun]

Δύο φορές το έχω διαπιστώσει όσο χρόνο χρησιμοποιώ ΜΤ.
Περισσότερες φορές (ποσοστιαία βάση χρόνου) έχει πέσει η google/fb/insta/tw.

[BillyVan]

Δύο φορές το έχω διαπιστώσει όσο χρόνο χρησιμοποιώ ΜΤ.
Περισσότερες φορές (ποσοστιαία βάση χρόνου) έχει πέσει η google/fb/insta/tw.

Το οτι δεν το διαπιστωσες δεν σημαινει οτι δεν εγινε παραπανω.

Οκ δε λεω κι εγω οπως ειπα να ειναι 4 ή 5 που το διαπιστωσα εγω....

Και στο κατω κατω αυτος που το εχει αναγκη το πληρωνει γιατι στο τζαμπα της Μικροτικ δεν ειναι και 100%

ασφαλες να στηριζεσαι παρόλο που παιζει άριστα.

Υπαρχουν και οι ευκολίες που έχεις με τα πληρωμενα με τα ονοματα domain που μπορεις να δωσεις.

Και τελος για καποιον επαγγελματια που δεν εχει μονο Μικροτικ βοηθουνε σε Μοντεμ, καταγραφικα κλπ.

Ειδικα το cname αν εχεις καποιο δικο σου domain ειναι must να δενεις το cloud της Μικροτικ με το domain που θες.

- - - Updated - - -

Mια χαρα διαθεση υπαρχει για αυτους που θελουν να μοιραστουν τα scripts και οσοι εχουν.

Μπορει να είμαι άδικος οκ.

Για να δούμε πόσοι θελουν να τα μοιραστουν.

- - - Updated - - -

Autobackup script

#### Modify these values to match your requirements ####
 
#Your email address to receive the backups
:local toemail "to email sas@gmail.com"
 
#The From address (you can use your own address if you want)
:local fromemail "to email sas@gmail.com"
 
#A mail server your machines can send through
:local emailserver "smtp.gmail.com"
 
############## Don’t edit below this line ##############
 
:local sysname [/system identity get name]
:local textfilename
:local backupfilename
:local time [/system clock get time]
:local date [/system clock get date]
:local newdate "";
:for i from=0 to=([:len $date]-1) do={ :local tmp [:pick $date $i];
:if ($tmp !="/") do={ :set newdate "$newdate$tmp" }
:if ($tmp ="/") do={}
}
#check for spaces in system identity to replace with underscores
:if ([:find $sysname " "] !=0) do={
:local name $sysname;
:local newname "";
:for i from=0 to=([:len $name]-1) do={ :local tmp [:pick $name $i];
:if ($tmp !=" ") do={ :set newname "$newname$tmp" }
:if ($tmp =" ") do={ :set newname "$newname_" }
}
:set sysname $newname;
}
:set textfilename ($"newdate" . "-" . $"sysname" . ".rsc")
:set backupfilename ($"newdate" . "-" . $"sysname" . ".backup")
:execute [/export file=$"textfilename" terse]
:execute [/system backup save name=$"backupfilename"]
#Allow time for export to complete
:delay 2s
 
#email copies
:log info "Emailing backups"
/tool e-mail send to=$"toemail" from=$"fromemail" server=[:resolve $emailserver] port=25 subject="[Config Backup] $sysname $time" file=$"textfilename"
#Send as different subjects to force GMail to treat as new message thread.
:local time [/system clock get time]
/tool e-mail send to=$"toemail" from=$"fromemail" server=[:resolve $emailserver] port=25 subject="[Config Backup] $sysname $time" file=$"backupfilename"
 
#Allow time to send
:delay 10s
 
#delete copies
/file remove $textfilename
/file remove $backupfilename

Κανει 2 αντιγραφα (ενα backup κι ενα rsc) του Μικροτικ σας και στη συνεχεια σας τα στελνει emai.

Το παραπανω σκριπτ για να παιξει σωστα πρεπει να εχετε φτιαξει μεσα στο

tools / email

ενα λογαριασμο δικο σας με τα στοιχεια σας.

[deniSun]

Και στο κατω κατω αυτος που το εχει αναγκη το πληρωνει γιατι στο τζαμπα της Μικροτικ δεν ειναι και 100%

Γι αυτό λέω ότι η σύγκριση MT cloud vs ddns (οποιουδήποτε)
δεν έχει σημασία.
Όλες οι εταιρίες έχουν down time.

Αυτός που το έχει ανάγκη για όσο δυνατόν μεγαλύτερο up time πάει σε λύσεις domain name + static ip.

[macro]

Το οτι δεν το διαπιστωσες δεν σημαινει οτι δεν εγινε παραπανω.

Οκ δε λεω κι εγω οπως ειπα να ειναι 4 ή 5 που το διαπιστωσα εγω....

Και στο κατω κατω αυτος που το εχει αναγκη το πληρωνει γιατι στο τζαμπα της Μικροτικ δεν ειναι και 100%

ασφαλες να στηριζεσαι παρόλο που παιζει άριστα.

Υπαρχουν και οι ευκολίες που έχεις με τα πληρωμενα με τα ονοματα domain που μπορεις να δωσεις.

Και τελος για καποιον επαγγελματια που δεν εχει μονο Μικροτικ βοηθουνε σε Μοντεμ, καταγραφικα κλπ.

Ειδικα το cname αν εχεις καποιο δικο σου domain ειναι must να δενεις το cloud της Μικροτικ με το domain που θες.

- - - Updated - - -



Μπορει να είμαι άδικος οκ.

Για να δούμε πόσοι θελουν να τα μοιραστουν.

- - - Updated - - -

Autobackup script

#### Modify these values to match your requirements ####
 
#Your email address to receive the backups
:local toemail "to email sas@gmail.com"
 
#The From address (you can use your own address if you want)
:local fromemail "to email sas@gmail.com"
 
#A mail server your machines can send through
:local emailserver "smtp.gmail.com"
 
############## Don’t edit below this line ##############
 
:local sysname [/system identity get name]
:local textfilename
:local backupfilename
:local time [/system clock get time]
:local date [/system clock get date]
:local newdate "";
:for i from=0 to=([:len $date]-1) do={ :local tmp [:pick $date $i];
:if ($tmp !="/") do={ :set newdate "$newdate$tmp" }
:if ($tmp ="/") do={}
}
#check for spaces in system identity to replace with underscores
:if ([:find $sysname " "] !=0) do={
:local name $sysname;
:local newname "";
:for i from=0 to=([:len $name]-1) do={ :local tmp [:pick $name $i];
:if ($tmp !=" ") do={ :set newname "$newname$tmp" }
:if ($tmp =" ") do={ :set newname "$newname_" }
}
:set sysname $newname;
}
:set textfilename ($"newdate" . "-" . $"sysname" . ".rsc")
:set backupfilename ($"newdate" . "-" . $"sysname" . ".backup")
:execute [/export file=$"textfilename" terse]
:execute [/system backup save name=$"backupfilename"]
#Allow time for export to complete
:delay 2s
 
#email copies
:log info "Emailing backups"
/tool e-mail send to=$"toemail" from=$"fromemail" server=[:resolve $emailserver] port=25 subject="[Config Backup] $sysname $time" file=$"textfilename"
#Send as different subjects to force GMail to treat as new message thread.
:local time [/system clock get time]
/tool e-mail send to=$"toemail" from=$"fromemail" server=[:resolve $emailserver] port=25 subject="[Config Backup] $sysname $time" file=$"backupfilename"
 
#Allow time to send
:delay 10s
 
#delete copies
/file remove $textfilename
/file remove $backupfilename

Κανει 2 αντιγραφα (ενα backup κι ενα rsc) του Μικροτικ σας και στη συνεχεια σας τα στελνει emai.

Το παραπανω σκριπτ για να παιξει σωστα πρεπει να εχετε φτιαξει μεσα στο

tools / email

ενα λογαριασμο δικο σας με τα στοιχεια σας.

Φιλε μου δε σε εξαναγκαζει κανενας να μοιραστεις οτι θες. Αν δε θες παλι θα σε αγαπαμε. Μη περιμενεις απο τους αλλους, αν θες να κανεις καντο, αν δε θες παλι οκ ειμαστε.

[BillyVan]

Καλη Κυριακη σε ολους.

@macro

Δεν ειναι και πυρηνικη φυσικη αυτο που ειπαμε να μοιραστουμε.

Εξαλλου αν καποιος εχει χρονο και δοκιμαζει μπορει να βρει τοσα στο ιντερνετ.

Αν ενοιωθα εξαναγκασμενος δε θα το εκανα ποτε.

Ισα ισα που απο μικρος κι εφοσον συμμετεχω σε φορουμ ειμαι πιστος στην αρχη του ¨η γνωση πρεπει να μοιραζεται¨.

Δεν ειναι κακο να μη ξερεις και να ρωτας.

Αυτο που μπορω κι οπου μπορω αν ξερω θα συμμετεχω.

Εσυ οπως κι αλλοι κανετε το ιδιο ακομη καλυτερα απο μενα.

[panosr]

Καλησπέρα

Το συγκεκριμένο script δίνει εύκολη πρόσβαση στα στατιστικά γραμμής και συσκευής του Speedport Plus.
Χρειάστηκα να το κάνω για να ενημερώνω αυτόματα το Max Limit στo Queue Tree καθώς η γραμμή μου δεν είναι σταθερή. Μπορείτε να το βρείτε και αυτό μέσα στα examples.
Πολύ πιθανό να δουλεύει και με το Speedport Entry 2i αλλά δεν έχω συσκευή για να το δοκιμάσω.

https://github.com/pror21/mikrotik-speedport-stats

[BillyVan]

Δοκιμασμένα

1

Wireguard resolve dns

System / scripts κανουμε ενα νεο και το βαζουμε.

Σε περίπτωση που αλλάξει ip ο σερβερ ανανεωνει την endpoint address κατι που το WG δεν κανει απο μονο του.

:foreach Peer in=[ /interface/wireguard/peers/find ] do={ /interface/wireguard/peers/set $Peer endpoint-address=[ get $Peer endpoint-address ]; }

2

Προσοχη εδω ψαχνει για comment "home"

αλλαξτε με το comment που εσεις εχετε στο peers

Μπορειτε να αφαιρεσετε το # για να βλεπετε τις πληροφοριες και στο log σας

αλλιως μονο στην περιπτωση που αλλαξει Ip θα παρετε το log warning οτι αλλαξε

:local ddnshost "billyvan.onoma.com"
:local peerip [/interface wireguard peers get [find comment="home"] endpoint-address ];
:local hostip [:resolve $ddnshost];
#:log info "peer endpoint ip address is $peerip";
#:log info "resolved ip address is $hostip"
:if ($peerip != $hostip) do={
/interface wireguard peers set [find comment="home"] endpoint-address=$hostip;
:log warning "Wireguard Peer endpoint IP Updated to: $hostip old IP was $peerip";
} else={
#:log info "WG: no need to update";
}

Το παραπανω πηγαινει και αλλαζει το Endpoint με την ip που θα κανει resolve.

Οποτε μη σας παραξενεψει οτι δεν εχετε πλεον εκει το dns name. (Αν το ξεχασετε υπαρχει μεσα στο σκριπτ)

Εχω κι άλλα, αλλά εβαλα αυτα τα δυο γιατι το 1 ειναι μια γραμμη και παιζει άριστα (γεμιζει το log ομως με wireguard peer entry changed by .....)

Αν εχεις 6 συνδεσεις οπως εγω ανα 2 λεπτα σου ερχονται 6 γραμμες απ το παραπανω και ειναι σπαστικο.

Το 2 επισης παιζει άριστα και μπορεις να εμφανισεις στο log μονο την αλλαγη ip για το hostname που πας να συνδεθεις οταν αυτη αλλαξει.

Θα πρεπει να κανετε τοσα σκριπτ οσα και οι συνδεσεις που κανετε και να αλλαξετε το σχόλιο home με το δικο σας για τη καθεμια.

Πλεον δουλευω με αυτο.

Πρεπει να βαλετε κι ενα schedule για να τρεχει ανα 2-3 λεπτα.

Αν μπορεσω να βρω τροπο σε ενα σκριπτ να μπορεις να βαλεις οσο ονοματα θελεις και να παιξει θα το συμπληρωσω.

Οτι δοκιμη εκανα δε μου βγηκε

[romankonis]

Endpoint βάζεις DDNS Cloud Mikrotik και Update κάθε 10 λεπτά και δεν χρειάζεται script.